answer "This will destroy your Bibliography Data!!" with "Continue" or "Stop"
if it is "Stop" then exit mouseUp
answer "Are you quite sure you want to do this?" with Yes or No
if it is "No" then exit mouseUp
put the number of this card into origCard
set lockScreen to true
put the number of lines in cardList into maxBkgndNum
repeat with bkgndCount = 1 to maxBkgndNum
put line bkgndCount of cardList into bName
go to bkgnd bName
put the number of cards of this background into numCards
repeat with cardToDelete = 2 to numCards
go to card 2 of bkgnd bName
put "Deleting Card " & cardToDelete & " of " & numCards & " from bkgnd " & line bkgndCount of cardList
doMenu "Delete Card"
end repeat
end repeat
-- Hide the dangerous buttons on this card.
go to card origCard
set lockScreen to false
set the rect of button "Dump Bkgnd Field Data" to 27,67,187,92
set the rect of button "Remake Bkgnd Fields" to 25,107,182,132
set the rect of button "Make Distribution Stack" to 254,70,427,94
-- Make the help fields unchangable.
go to first card of background Help
repeat while the short name of this background is "Help"
set the locktext of field Topic to true
set the lockText of card field help to true
if the style of card field help is "scrolling" then
set the scroll of card field help to 0
end if
go to next card
end repeat
-- Make the non-bibliography cards undeletable.
go to card 1
repeat with x = 1 to firstRefCard-1
set the cantDelete of this card to true
go to next card
end repeat
-- Get rid of stray buttons on the first card.
go to card 1
select card button "Developer Stack"
doMenu "Clear Button"
select card button "foobar"
doMenu "Clear Button"
choose browse tool
end mouseUp
-- part 3 (button)
-- low flags: 00
-- high flags: 8003
-- rect: left=27 top=67 right=92 bottom=187
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Dump Bkgnd Field Data
----- HyperTalk script -----
on mouseUp
global cardList, dumpFile
set cursor to 4
push card
set lockscreen to true
-- Make a list of items for the xcmd
put cardlist into tempList
-- Convert returns to commas
repeat with x = 1 to length of tempList
if char x of tempList = return then
put "," into char x of tempList
end if
end repeat
put "Pick the backgrounds to dump."
DoList "Dump","Cancel", tempList, ONE
put empty into message
hide message
if the result is empty then exit mouseUp
put item 2 of the result into bkgndName
-- Select a file to dump to
put NewFileName("Save dump to",dumpFile) into temp
put empty into message
hide message
if temp is empty then exit mouseUp
set cursor to 4
put temp into dumpFile
open file dumpFile
go to bkgnd bkgndName
put the number of bkgnd fields into numFields
repeat with x = 1 to numFields
write "bkgnd" to file dumpFile
write tab & the short name of field x to file dumpFile
write tab & the location of field x to file dumpFile
write tab & the lockText of field x to file dumpFile
write tab & the rectangle of field x to file dumpFile
write tab & the showlines of field x to file dumpFile
write tab & the style of field x to file dumpFile
write tab & the textAlign of field x to file dumpFile
write tab & the textFont of field x to file dumpFile
write tab & the textHeight of field x to file dumpFile
write tab & the textSize of field x to file dumpFile
write tab & the visible of field x to file dumpFile
write tab & the wideMargins of field x to file dumpFile
write tab & the script of field x to file dumpFile
write tab to file dumpFile
write return to file dumpFile
end repeat
close file dumpFile
-- save the file name
put LastPathComponent(dumpFile) into dumpFile
hide message
pop card
end mouseUp
-- part 4 (button)
-- low flags: 00
-- high flags: 8003
-- rect: left=25 top=107 right=132 bottom=182
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Remake Bkgnd Fields
----- HyperTalk script -----
on mouseUp
global cardList, dumpFile
set cursor to 4
push card
set lockscreen to true
-- Make a list of items for the xcmd
put cardlist into tempList
-- Convert returns to commas
repeat with x = 1 to length of tempList
if char x of tempList = return then
put "," into char x of tempList
end if
end repeat
put "Pick the background to remake."
DoList "Remake","Cancel", tempList, ONE
if the result is empty then
put empty into message
hide message
exit mouseUp
end if
put item 2 of the result into bkgndName
-- Select a file to open
put "Pick the file with the field information."
put FileName("TEXT") into temp
put empty into message
hide message
if temp is empty then exit mouseUp
set cursor to 4
put temp into dumpFile
open file dumpFile
go to bkgnd bkgndName
-- delete all the old fields
put the number of bkgnd fields into numFields
repeat with x = 1 to numFields
select bkgnd field 1
doMenu "Clear Field"
end repeat
doMenu "Background"
repeat while true
read from file dumpFile until tab -- this field says card or bkgnd
put it into fieldType
if fieldType is empty or fieldType is return then exit repeat
play "harpsichord" "Ct6"
-- Switch to card, as opposed to bkgnd.
if fieldType is "card" then set editBkgnd to false
doMenu "New Field"
put the number of bkgnd fields into x
set the name of bkgnd field x to readField(dumpFile)
put readField(dumpFile) into temp
set loc of bkgnd field x to temp
set the lockText of bkgnd field x to readField(dumpFile)
put readField(dumpFile) into temp
set the rectangle of field x to temp
set the showlines of field x to readField(dumpFile)
set the style of field x to readField(dumpFile)
set the textAlign of field x to readField(dumpFile)
set the textFont of field x to readField(dumpFile)
set the textHeight of field x to readField(dumpFile)
set the textSize of field x to readField(dumpFile)
set the visible of field x to readField(dumpFile)
set the wideMargins of field x to readField(dumpFile)
set the script of field x to readField(dumpFile)
read from file dumpFile until return
if fieldType is "card" then set editBkgnd to true
end repeat
close file dumpFile
-- save the file name
put LastPathComponent(dumpFile) into dumpFile
hide message
pop card
choose browse tool
put "Remade fields on background " & bkgndName
beep
end mouseUp
-- part 1 (field)
-- low flags: 01
-- high flags: 0007
-- rect: left=7 top=59 right=286 bottom=504
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 0
-- font id: 34
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: help
-- part contents for background part 6
----- text -----
Technical Information
-- part contents for card part 1
----- text -----
This stack is arranged as follows:
Card 1
Card named "Intro", background named "Intro". Has a bunch of buttons, and is the only location of the
stack dumping buttons.
Card 2
Card named "Journal Names", background named "Names". It contains one field holding the journal names for the journal button. Upon closing this card the journalList, the list of names the button displays, is remade.
Cards 3 through 11
The help cards. No card name, background named "Help". Usually just two fields: one line about the topic, and then a big field containing the information. Some cards contain example buttons that are usually disabled.
Card 12
This card exists only so the stack can tell where the reference cards begin. This is done only when the stack opens, so if you add more cards before this, the global variable firstRefCard, the number of the first card containing bibliography information, will not be correct. You will get a message about a button "Unix" not being found. To fix this, either leave the stack and return, or set firstRefCard by hand.
Cards 13 through the end.
These cards contain the bibliography data. There are 14 different backgrounds, but each had the same number of fields to avoid problems with find. Unused fields are stored on the right side of the card and should never have information put in them.
Most of the interesting code is in the stack script. The script of the buttons on the left side of the card ("Card Type...", etc.) simply call the command in the stack script. This was done so that code changes occurred in only one place, instead of in 14 button scripts on 14 different backgrounds.
The makeBib command could easily be faster by moving subcommands up into higher level commands, such as putting the doLine code in authorLine, or putting the authorLine code in ArticleBib. If the time to write out the .bib file becomes intolerable, I will do that, but right now the code is flexible and easy to understand, and the delay doesn't bother me. You don't make .bib files too often, anyway.
If you create a new handler for a sytle of bibliography output that you need, you would modify the "makeBib" handler in the stack script. Add your item to "bibList" so it will be displayed in the menu, and a few lines below that I indicate where your handler would be called.
Special buttons for the technically sophisticated:
For people who will actually muck around in the stack, I have included 3 buttons
hidden behind this field. Don't pull them out unless you know what you are doing. As long as they are hidden, they are harmless. Misused, they can destroy your stack. What they do:
"Make Distribution Stack": deletes all data cards except one of each type and hides the special buttons on this card.
Dump Bkgnd Field Data: goes to the bibliography backgound(s) of your choice and dumps all the information about the background fields to a text file. Written out in the form of pieces of field information ended by tabs, and separate field data separated by returns, this dumps *everything* about a field except its contents: name, rect, locktext, font, etc.
Remake Bkgnd Fields: this is the opposite of the previous button. Given a background (you can pick only one) and a file containing field data, this deletes all the background fields on that background and makes new fields using the data in the text file. The fields are created in the order they are read in.
(Walnut Creek)(1995).ISO/biblio/bibtex/mac/bib.hqx/Bib Stack/card_9293_render.png){kind=link}
(Walnut Creek)(1995).ISO/biblio/bibtex/mac/bib.hqx/Bib Stack/PATs.png){kind=link}